mirror of
https://codeberg.org/dnkl/yambar.git
synced 2025-04-23 12:35:41 +02:00
6113f9b94e
Introduce a new icon particle. It follows the icon spec (https://specifications.freedesktop.org/icon-theme-spec/latest/index.html). Rendering logic is taken from fuzzel (using nanosvg + libpng), while loading logic is taken from sway. Standard usage is with `use-tag = false` which expands the provided string template and then loads the string as the icon name. There are settings to manually override the base paths, themes, etc. The second usage which is required for tray support is a special icon tag that transfers raw pixmaps. With `use-tag = true` it first expands the string, and then uses that output to find an icon pixmap tag. To reduce memory usage, themes are reference counted so they can be passed down the configuration stack without having to load them in multiple times. For programmability, a fallback particle can be specified if no icon/tag is found `fallback: ...`. And the new icon pixmap tag can be existence checked in map conditions using `+{tag_name}`. Future work to be done in follow up diffs: 1. Icon caching. Currently performs an icon lookup on each instantiation & a render on each refresh. 2. Theme caching. Changing theme directories results in a new "theme collection" being created resulting in the possibility of duplicated theme loading.
132 lines
3.4 KiB
Text
132 lines
3.4 KiB
Text
%{
|
|
#include <stdio.h>
|
|
#include <string.h>
|
|
|
|
#include "map.h"
|
|
|
|
struct map_condition *MAP_CONDITION_PARSE_RESULT;
|
|
char *MAP_PARSER_ERROR_MSG;
|
|
|
|
static const int NUM_TOKENS = 7;
|
|
int yylex();
|
|
void yyerror(const char *str);
|
|
%}
|
|
|
|
%define parse.lac full
|
|
%define parse.error custom
|
|
|
|
%union {
|
|
char *str;
|
|
struct map_condition *condition;
|
|
enum map_op op;
|
|
}
|
|
|
|
%token WORD STRING CMP_OP L_PAR R_PAR AT
|
|
%left BOOL_OP
|
|
%precedence NOT
|
|
|
|
%destructor { free_map_condition($<condition>$); } condition
|
|
%destructor { free($<str>$); } WORD
|
|
%destructor { free($<str>$); } STRING
|
|
|
|
%%
|
|
result: condition { MAP_CONDITION_PARSE_RESULT = $<condition>1; };
|
|
|
|
condition:
|
|
AT WORD {
|
|
$<condition>$ = malloc(sizeof(struct map_condition));
|
|
$<condition>$->tag = $<str>2;
|
|
$<condition>$->op = MAP_OP_ICON_TAG;
|
|
}
|
|
|
|
|
WORD {
|
|
$<condition>$ = malloc(sizeof(struct map_condition));
|
|
$<condition>$->tag = $<str>1;
|
|
$<condition>$->op = MAP_OP_SELF;
|
|
}
|
|
|
|
|
WORD CMP_OP WORD {
|
|
$<condition>$ = malloc(sizeof(struct map_condition));
|
|
$<condition>$->tag = $<str>1;
|
|
$<condition>$->op = $<op>2;
|
|
$<condition>$->value = $<str>3;
|
|
}
|
|
|
|
|
WORD CMP_OP STRING {
|
|
$<condition>$ = malloc(sizeof(struct map_condition));
|
|
$<condition>$->tag = $<str>1;
|
|
$<condition>$->op = $<op>2;
|
|
$<condition>$->value = $<str>3;
|
|
}
|
|
|
|
|
L_PAR condition R_PAR { $<condition>$ = $<condition>2; }
|
|
|
|
|
NOT condition {
|
|
$<condition>$ = malloc(sizeof(struct map_condition));
|
|
$<condition>$->cond1 = $<condition>2;
|
|
$<condition>$->op = MAP_OP_NOT;
|
|
}
|
|
|
|
|
condition BOOL_OP condition {
|
|
$<condition>$ = malloc(sizeof(struct map_condition));
|
|
$<condition>$->cond1 = $<condition>1;
|
|
$<condition>$->op = $<op>2;
|
|
$<condition>$->cond2 = $<condition>3;
|
|
}
|
|
;
|
|
%%
|
|
|
|
void yyerror(const char *str)
|
|
{
|
|
fprintf(stderr, "error: %s\n", str);
|
|
}
|
|
|
|
static char const*
|
|
token_to_str(yysymbol_kind_t tkn)
|
|
{
|
|
switch (tkn) {
|
|
case YYSYMBOL_CMP_OP: return "==, !=, <=, <, >=, >";
|
|
case YYSYMBOL_BOOL_OP: return "||, &&";
|
|
case YYSYMBOL_L_PAR: return "(";
|
|
case YYSYMBOL_R_PAR: return ")";
|
|
case YYSYMBOL_NOT: return "~";
|
|
case YYSYMBOL_AT: return "+";
|
|
default: return yysymbol_name(tkn);
|
|
}
|
|
}
|
|
|
|
static int
|
|
yyreport_syntax_error (const yypcontext_t *ctx)
|
|
{
|
|
int res = 0;
|
|
char *errmsg = malloc(1024);
|
|
errmsg[0] = '\0';
|
|
|
|
// Report the tokens expected at this point.
|
|
yysymbol_kind_t expected[NUM_TOKENS];
|
|
int n = yypcontext_expected_tokens(ctx, expected, NUM_TOKENS);
|
|
if (n < 0)
|
|
res = n; // Forward errors to yyparse.
|
|
else {
|
|
for (int i = 0; i < n; ++i) {
|
|
strcat(errmsg, i == 0 ? "expected [" : ", ");
|
|
strcat(errmsg, token_to_str(expected[i]));
|
|
}
|
|
strcat(errmsg, "]");
|
|
}
|
|
|
|
// Report the unexpected token.
|
|
yysymbol_kind_t lookahead = yypcontext_token(ctx);
|
|
if (lookahead != YYSYMBOL_YYEMPTY) {
|
|
strcat(errmsg, ", found ");
|
|
if (!(lookahead == YYSYMBOL_STRING || lookahead == YYSYMBOL_WORD))
|
|
strcat(errmsg, yysymbol_name(lookahead));
|
|
else if (yylval.str != NULL)
|
|
strcat(errmsg, yylval.str);
|
|
else
|
|
strcat(errmsg, "nothing");
|
|
}
|
|
|
|
MAP_PARSER_ERROR_MSG = errmsg;
|
|
return res;
|
|
}
|